#include  "msp430x12x2.h"
;******************************************************************************
;   MSP-FET430P120 Demo - ADC10 Sample A10 64x, 1.5v, Repeat Single DTC DCO
;
;   Description; Use DTC to sample A10 64 times with reference to internal 1.5v.
;   Vref Software writes to ADC10SC to trigger sample burst. In Mainloop MSP430 
;   waits in LPM0 to save power until ADC10 conversion complete, ADC10_ISR(DTC)
;   will force exit from any LPMx in Mainloop on reti. (ADC10OSC/4)/64 
;   determines sample time which needs to be greater than 30us for temperature
;   sensor. DTC transfers conversion code to RAM 200h - 280h. P1.0 set at start
;   of conversion burst, reset oncompletion. Temperature sensor offset and slope
;   will vary from device to device per datasheet tolerence. 
;   //*MSP430F1232 or MSP430F1132 Device Required*//
;
;                MSP430F1232
;             -----------------
;         /|\|              XIN|-  
;          | |                 |
;          --|RST          XOUT|-
;            |                 |
;            |A10          P1.0|-->LED
;
;   M.Buccini
;   Texas Instruments, Inc
;   January 2002 A
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     0E000h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #0300h,SP               ; Initialize stackpointer
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; Stop WDT
SetupADC10  mov.w   #INCH_10+ADC10DIV_3+CONSEQ_2,&ADC10CTL1 ;
            mov.w   #SREF_1+ADC10SHT_3+MSC+REFON+ADC10ON+ADC10IE,&ADC10CTL0 ; 
            mov.b   #040h,&ADC10DTC1        ; 64 conversions   
SetupP1     bis.b   #001h,&P1DIR            ; P1.0 output
                                            ;
Mainloop    bic.w   #ENC,&ADC10CTL0         ; 
busy_test   bit     #BUSY,&ADC10CTL1        ; Insure  ADC10 core inactive
            jnz     busy_test               ;
            mov.w   #0200h,&ADC10SA         ; Data buffer start
            bis.b   #001h,&P1OUT            ; P1.0 =1 
            bis.w   #ENC+ADC10SC,&ADC10CTL0 ; Start sampling
            bis.w   #CPUOFF+GIE,SR          ; LPM0, ADC12 ISR will force exit
            bic.b   #001h,&P1OUT            ; P1.0 = 0 
            jmp     Mainloop                ; Again
                                            ;
;------------------------------------------------------------------------------ 
ADC10_ISR;   
;------------------------------------------------------------------------------ 
            mov.w   #GIE,0(SP)              ; Exit any LPMx on reti
            reti                            ;		 
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors Used MSP430x12x2         
;------------------------------------------------------------------------------ 
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ; 
            ORG     0FFEAh                  ; ADC10 Vector
            DW      ADC10_ISR               ; 
            END
