#include  "msp430x11x1.h"
;******************************************************************************
;   MSP-FET430x110 Demo - Timer_A Toggle P1.1 With TA0 up-downmode, 32kHz ACLK 
;
;   Description; Toggle P1.1 using hardware TA0 output. Timer_A is configured
;   in up-downmode with CCR0 defining period, TA0 also output on P1.1. In this 
;   example, CCR0 is loaded with 5 and TA0 will toggling P.1 at TACLK/2*5.
;   Thus the ouput frequency on P1.1 will be the TACLK/20. No CPU or software 
;   resources required. Normal mode LPM3.
;   ACLK = TACLK = 32kHz, MCLK = default DCO ~ 800kHz
;   As coded with TACLK = ACLK, P1.1 output frequency = 32768/20 = 1.6384kHz
;   //*External watch crystal installed on XIN XOUT is required for ACLK*//	  
;
;                MSP430F1121
;             -----------------
;         /|\|              XIN|-  
;          | |                 | 32kHz
;          --|RST          XOUT|-
;            |                 |
;            |             P1.1|-->TA0 ACLK/20
;
;   M.Buccini
;   Texas Instruments, Inc
;   January 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     0F000h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #300h,SP                ; Initialize stackpointer
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; Stop WDT
SetupTA     mov.w   #TASSEL0+TACLR,&TACTL   ; ACLK, clear TAR
SetupC0     mov.w   #OUTMOD_4,&CCTL0        ; CCR0 toggle mode
            mov.w   #5,&CCR0                ; 
SetupP1     bis.b   #002h,&P1DIR            ; P1.1 output 
            bis.b   #002h,&P1SEL            ; P1.1 option slect 
            bis.w   #MC1+MC0,&TACTL         ; Start Timer_a in up-downmode
                                            ;						  
Mainloop    bis.w   #LPM3,SR                ; Enter LPM3
            nop                             ; Required for C-spy
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors Used MSP430x11x1         
;------------------------------------------------------------------------------ 
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ; 
            END
